# --------------------------------------------
# HEWLETT·PACKARD 15C Simulator program
# Created with version 3.0.RC2
# --------------------------------------------
#T:Natural Log of Gamma Function (complex)
#D:This program computes the Natural Log of the Gamma Function for complex numbers.\n\nPut a Complex number in the X register and press the A function key.  (Computes the Ln of the Gamma Function of the complex number in X).\n\nNote: Gamma of (6 + i0) is equivalent to 5 Factorial.  So if you enter 6 then press A and e<sup>x</sup> the result will be 120 the same as 5 !.\n\nThis program is only accurate when the Real component is a positive number (between 0 and 70.9).
#L-1:Compute Ln of Gamma Function (complex)
#L1:Loop for continued fraction
#R0:Conversion Constant 1
#R1:Conversion Constant 2
#R2:Conversion Constant 3
#R3:Conversion Constant 4
#R4:Conversion Constant 5
#R5:Conversion Constant 6
#R6:Conversion Constant 7
#R7:Save Real Component
#R8:Save Imaginary Component
#R(i):Lookup of each Conversion Constant
#RI:Index into conversion constants list
#F8:Complex Mode
# --------------------------------------------

   000 {             } 
   001 {    42 21 11 } f LBL A
   002 {       44  7 } STO 7
   003 {       42 30 } f Re ↔ Im
   004 {       44  8 } STO 8
   005 {    43  5  8 } g CF 8
   006 {       43 35 } g CLx
   007 {           2 } 2
   008 {       43 26 } g π
   009 {          20 } ✕
   010 {       43 12 } g LN
   011 {           2 } 2
   012 {          10 } ÷
   013 {       44  0 } STO 0
   014 {           1 } 1
   015 {           2 } 2
   016 {          15 } 1/x
   017 {       44  1 } STO 1
   018 {           3 } 3
   019 {           0 } 0
   020 {          15 } 1/x
   021 {       44  2 } STO 2
   022 {           5 } 5
   023 {           3 } 3
   024 {          36 } ENTER
   025 {           2 } 2
   026 {           1 } 1
   027 {           0 } 0
   028 {          10 } ÷
   029 {       44  3 } STO 3
   030 {           1 } 1
   031 {           9 } 9
   032 {           5 } 5
   033 {          36 } ENTER
   034 {           3 } 3
   035 {           7 } 7
   036 {           1 } 1
   037 {          10 } ÷
   038 {       44  4 } STO 4
   039 {           1 } 1
   040 {          48 } .
   041 {           0 } 0
   042 {           1 } 1
   043 {           1 } 1
   044 {           5 } 5
   045 {           2 } 2
   046 {           3 } 3
   047 {           0 } 0
   048 {           6 } 6
   049 {           8 } 8
   050 {       44  5 } STO 5
   051 {           1 } 1
   052 {          48 } .
   053 {           5 } 5
   054 {           1 } 1
   055 {           7 } 7
   056 {           4 } 4
   057 {           7 } 7
   058 {           3 } 3
   059 {           6 } 6
   060 {           4 } 4
   061 {           9 } 9
   062 {       44  6 } STO 6
   063 {       45  7 } RCL 7
   064 {       45  8 } RCL 8
   065 {       42 25 } f I
   066 {           6 } 6
   067 {       44 25 } STO I
   068 {          34 } x↔y
   069 {          36 } ENTER
   070 {          36 } ENTER
   071 {          36 } ENTER
   072 {       45  6 } RCL 6
   073 {    42 21  1 } f LBL 1
   074 {          40 } ✛
   075 {       45 24 } RCL (i)
   076 {          34 } x↔y
   077 {          10 } ÷
   078 {    42  5 25 } f DSE I
   079 {       22  1 } GTO 1
   080 {       45  0 } RCL 0
   081 {          40 } ✛
   082 {          34 } x↔y
   083 {          30 } −
   084 {       43 36 } g LSTx
   085 {       43 12 } g LN
   086 {       43 36 } g LSTx
   087 {          48 } .
   088 {           5 } 5
   089 {          30 } −
   090 {          20 } ✕
   091 {          40 } ✛
   092 {       43 32 } g RTN

# --------------------------------------------